Programming Praxis

The Standard Prelude makes tasks like this easy; we will use list-of (fold-of), sum, square, digits, ilog and permutations.

The first task is just a list comprehension that generates three-digit numbers and tests them for the required properties:

> (list-of n
    (n range 100 1000)
    (zero? (modulo n 11))
    (= (/ n 11)
       (sum (map square (digits n)))))
(550 803)

The second task calls for us to dissect a number and stitch it back together, looping until we find the answer:

> (let loop ((n 6))
    (let ((m (+ (* 6 (expt 10 (ilog 10 n))) (quotient n 10))))
      (if (= (* 4 n) m) n
        (loop (+ n 10)))))
153846

The third task is a bit harder. In-position and two-consecutive count the number of contestants in the specified positions; the list comprehension loops over the permutations of (A B C D E), testing each one.

(define (in-position actual predicted)
  (let loop ((a actual) (p predicted) (n 0))
    (cond ((null? a) n)
          ((equal? (car a) (car p))
            (loop (cdr a) (cdr p) (+ n 1)))
          (else (loop (cdr a) (cdr p) n)))))

(define (two-consecutive actual predicted)
  (let loop ((a actual) (p predicted) (n 0))
    (cond ((or (null? a) (null? p)) n)
          ((null? (cdr p)) n)
          ((null? (cdr a))
            (loop actual (cdr p) n))
          ((and (equal? (car a) (car p))
                (equal? (cadr a) (cadr p)))
            (loop (cddr a) p (+ n 1)))
          (else (loop (cdr a) p n)))))

> (list-of p
    (p in (permutations '(a b c d e)))
    (= (in-position p '(a b c d e)) 0)
    (= (two-consecutive p '(a b c d e)) 0)
    (= (in-position p '(d a e c b)) 2)
    (= (two-consecutive p '(d a e c b)) 2))
((e d a c b))

You can run the suggested solution at http://programmingpraxis.codepad.org/JRGmt2wZ.

Pages: 1 2